NUnit and COBOL.Net

A while back, I spent a afternoon converting some C# NUnit documentation into COBOL .Net, so I thought I would share the document with the world, with the hope that it will help any one interested in using NUnit and COBOL.

Enjoy!


Let’s start with a simple example. Suppose we are writing a bank application and we have a basic domain class – Account. Account supports operations to deposit, withdraw, and transfer funds. The Account class may look like this:

class-id. Account as "Account".
environment division.
configuration section.
repository.
object.
data division.
working-storage section.
01 balance comp-2 value 0 property as "Balance".

method-id. "Deposit".
local-storage section.
linkage section.
01 lnk-amount comp-2.
procedure division using by value lnk-amount.
add lnk-amount to balance
exit method.
end method "Deposit".

method-id. "Withdraw".
local-storage section.
linkage section.
01 lnk-amount comp-2.
procedure division using by value lnk-amount.
subtract lnk-amount from balance
exit method.
end method "Withdraw".

method-id. "TransferFunds".
local-storage section.
linkage section.
01 lnk-Account object reference Account.
01 lnk-amount comp-2.
procedure division using by value lnk-Account,
by value lnk-amount.
exit method.
end method "TransferFunds".
end object.
end class Account.

Now let’s write a test for this class – AccountTest. The first method we will test is TransferFunds.

$set preservecase
class-id. AccountTest as "AccountTest".

environment division.
configuration section.
repository.
class sys-single as "System.Single"
class cls-TestFixture as "NUnit.Framework.TestFixtureAttribute"
class cls-Test as "NUnit.Framework.TestAttribute"
class Assert as "NUnit.Framework.Assert"

class cls-Account as "Account"
.

class-attributes.
custom-attribute is cls-TestFixture.

static.
data division.
working-storage section.
end static.

object.
method-id. "TransferFunds" custom-attribute is cls-Test.
local-storage section.
01 src object reference cls-Account.
01 dest object reference cls-Account.
procedure division.
set src to cls-Account::"New"
invoke src::"Deposit"(200)

set dest to cls-Account::"New"
invoke dest::"Deposit"(150)

invoke src::"TransferFunds"(dest, 100);

invoke Assert::"AreEqual"(250 as sys-single,dest::"Balance")
invoke Assert::"AreEqual"(100 as sys-single,src::"Balance")
exit method.
end method "TransferFunds".
end object.
end program AccountTest.

The first thing to notice about this class is that it has a TestFixture attribute associated with it – this is the way to indicate that the class contains test code (this attribute can be inherited). The class has to be public and there are no restrictions on its superclass. The class also has to have a default constructor.

The only method in the class – TransferFunds, has a Test attribute associated with it – this is an indication that it is a test method. Test methods have to return void and take no parameters. In our test method we do the usual initialization of the required test objects, execute the tested business method and check the state of the business objects. The Assert class defines a collection of methods used to check the post-conditions and in our example we use the AreEqual method to make sure that after the transfer both accounts have the correct balances (there are several overloadings of this method, the version that was used in this example has the following parameters : the first parameter is an expected value and the second parameter is the actual value).

Compile and run this example. Assume that you have compiled your test code into a Example1.dll. Start the NUnit Gui (the installer will have created a shortcut on your desktop and in the “Program Files” folder), after the GUI starts, select the File->Open menu item, navigate to the location of your bank.dll and select it in the “Open” dialog box. When the bank.dll is loaded you will see a test tree structure in the left panel and a collection of status panels on the right. Click the Run button, the status bar and the TransferFunds node in the test tree turn red – our test has failed. The “Errors and Failures” panel displayed the following message – “TransferFunds : expected <250> but was <150>” and the stack trace panel right below it reported where in the test code the failure has occurred “at AccountTest.TransferFunds() in xxxxExample1Example1AccountTest.cbl:line 42”

That is expected behavior; the test has failed because we have not implemented the TransferFunds method yet. Now let’s get it to work. Don’t close the GUI and go back to your IDE and fix the code, make your TransferFunds method look like this:

method-id. "TransferFunds".
local-storage section.
linkage section.
01 lnk-Account object reference Account.
01 lnk-amount comp-2.
procedure division using by value lnk-Account,
by value lnk-amount.
invoke lnk-Account::"Deposit"(lnk-amount)
invoke self::"Withdraw"(lnk-amount)
exit method.
end method "TransferFunds".

Now recompile your code and click the run button in GUI again – the status bar and the test tree turn green. (Note how the GUI has reloaded the assembly automatically for you; we will keep the GUI open all the time and continue working with our code in IDE and write more tests).

Let’s add some error checking to our Account code. We are adding the minimum balance requirement for the account to make sure that banks continue to make their money by charging your minimal overdraft protection fee. Let’s add the minimum balance property to our Account class:


01 minimumBalance comp-2 value 10
property as "MinimumBalance".

We will use an exception to indicate an overdraft:


class-id. InsufficientFundsException
as "InsufficientFundsException"
inherits cls-exception.

repository.
class cls-exception as "System.ApplicationException".
object.
object-storage section.
end object.

end class InsufficientFundsException.

Add two new classes reference to the repository:


class ExpectedException
as "NUnit.Framework.ExpectedExceptionAttribute"
class InsufficientFundsException
as "InsufficientFundsException"

Add a new test method to our AccountTest class:


method-id. "TransferWithInsufficientFunds"
custom-attribute is cls-Test
custom-attribute is ExpectedException(
type of InsufficientFundsException)
.
local-storage section.
01 src object reference cls-Account.
01 dest object reference cls-Account.
procedure division.
set src to cls-Account::"New"
invoke src::"Deposit"(200)

set dest to cls-Account::"New"
invoke dest::"Deposit"(150)

invoke src::"TransferFunds"(dest, 300);
exit method.
end method "TransferWithInsufficientFunds".

This test method in addition to Test attribute has an ExpectedException attribute associated with it – this is the way to indicate that the test code is expecting an exception of a certain type; if such an exception is not thrown during the execution – the test will fail.

Compile your code and go back to the GUI. As you compiled your test code, the GUI has grayed out and collapsed the test tree as if the tests were not run yet (GUI watches for the changes made to the test assemblies and updates itself when the structure of the test tree has changed – e.g. new test is added). Click the “Run” button – we have a red status bar again. We got the following Failure : “TransferWithInsufficentFunds : InsufficientFundsException was expected”. Let’s fix our Account code again, modify the TransferFunds method this way:


method-id. "TransferFunds".
local-storage section.
linkage section.
01 lnk-Account object reference Account.
01 lnk-amount comp-2.
procedure division using by value lnk-Account,
by value lnk-amount.

invoke lnk-Account::"Deposit"(lnk-amount)
if balance - lnk-amount < minimumBalance raise InsufficientFundsException::"New"() end-if invoke self::"Withdraw"(lnk-amount) exit method. end method "TransferFunds".

Compile and run the tests – green bar. Success! But wait, looking at the code we’ve just written we can see that the bank may be loosing money on every unsuccessful funds Transfer operation. Let’s write a test to confirm our suspicions. Add this test method:


method-id. "TransferWithInsufficientFundsAtomicity"
custom-attribute is cls-Test
.
local-storage section.
01 src object reference cls-Account.
01 dest object reference cls-Account.
01 obj-InsufficientFundsException
object reference InsufficientFundsException.
procedure division.
set src to cls-Account::"New"
invoke src::"Deposit"(200)

set dest to cls-Account::"New"
invoke dest::"Deposit"(150)

try
invoke src::"TransferFunds"(dest, 300)
catch obj-InsufficientFundsException
continue
end-try

invoke Assert::"AreEqual"(200 as sys-single,src::"Balance")
invoke Assert::"AreEqual"(150 as sys-single,dest::"Balance")

exit method.
end method "TransferWithInsufficientFundsAtomicity".

We are testing the transactional property of our business method – all operations are successful or none. Compile and run – red bar. OK, we’ve made $300.00 out of a thin air (1999.com déjà vu?) – the source account has the correct balance of 150.00 but the destination account shows : $450.00. How do we fix this? Can we just move the minimum balance check call in front of the updates:


method-id. "TransferFunds".
local-storage section.
linkage section.
01 lnk-Account object reference Account.
01 lnk-amount comp-2.
procedure division using by value lnk-Account,
by value lnk-amount.

if balance - lnk-amount < minimumBalance raise InsufficientFundsException::"New"() end-if invoke lnk-Account::"Deposit"(lnk-amount) invoke self::"Withdraw"(lnk-amount) exit method. end method "TransferFunds".

What if the Withdraw() method throws another exception? Should we execute a compensating transaction in the catch block or rely on our transaction manager to restore the state of the objects? We need to answer those questions at some point, but not now; but what do we do with the failing test in the meantime – remove it? A better way is to temporarily ignore it, add the following attribute to your test method


method-id. "TransferWithInsufficientFundsAtomicity"
custom-attribute is cls-Test
custom-attribute is
IgnoreTest("Need to decide how to implement transaction management in the application")

Compile and run – yellow bar. Click on “Tests Not Run” tab and you will see AccountTest.TransferWithInsufficientFundsAtomicity() in the list along with the Reason this test is ignored.

Looking at our test code we can see that some refactoring is in order. All test methods share a common set of test objects. Let’s extract this initialization code into a setup method and reuse it in all of our tests. The refactored version of our test class looks like this:


$set preservecase sourceformat"free"
class-id. AccountTest as "AccountTest".

environment division.
configuration section.
repository.
class sys-single as "System.Single"
class NUnit-TestFixture as
"NUnit.Framework.TestFixtureAttribute"
class NUnit-Test as
"NUnit.Framework.TestAttribute"
class NUnit-Setup as
"NUnit.Framework.SetUpAttribute"
class NUnit-Assert as
"NUnit.Framework.Assert"
class NUnit-IgnoreTest as
"NUnit.Framework.IgnoreAttribute"
class NUnit-ExpectedException as
"NUnit.Framework.ExpectedExceptionAttribute"

class cls-Account as
"Account"
class InsufficientFundsException as
"InsufficientFundsException"
.

class-attributes.
custom-attribute is NUnit-TestFixture.

object.
working-storage section.
01 src object reference cls-Account.
01 dest object reference cls-Account.

method-id. "Init"
custom-attribute is NUnit-Setup.
procedure division.
set src to cls-Account::"New"
set dest to cls-Account::"New"

invoke src::"Deposit"(200)
invoke dest::"Deposit"(150)
exit method.
end method "Init".

method-id. "TransferFunds"
custom-attribute is NUnit-Test.
procedure division.
invoke src::"TransferFunds"(dest, 100);
invoke NUnit-Assert::"AreEqual"(250,dest::"Balance")
invoke NUnit-Assert::"AreEqual"(100,src::"Balance")
exit method.
end method "TransferFunds".

method-id. "TransferWithInsufficientFunds"
custom-attribute is NUnit-Test
custom-attribute is
NUnit-ExpectedException(
type of InsufficientFundsException).
procedure division.
invoke src::"TransferFunds"(dest, 300)
exit method.
end method "TransferWithInsufficientFunds".

method-id. "TransferWithInsufficientFundsAtomicity"
custom-attribute is NUnit-Test
custom-attribute is NUnit-IgnoreTest(
"Need to decide how to implement transaction management in the application").
local-storage section.
01 obj-InsufficientFundsException
object reference InsufficientFundsException.
procedure division.
try
invoke src::"TransferFunds"(dest, 300)
catch obj-InsufficientFundsException
continue
end-try

invoke NUnit-Assert::"AreEqual"(
200 as sys-single,src::"Balance")
invoke NUnit-Assert::"AreEqual"(
150 as sys-single,dest::"Balance")
exit method.
end method "TransferWithInsufficientFundsAtomicity".

end object.
end program AccountTest.

Note that Init method has the common initialization code, it has void return type, no parameters, and it is marked with SetUp attribute. Compile and run – same yellow bar!

This entry was posted in COBOL, NUnit, Tips and tagged , . Bookmark the permalink.

2 Responses to NUnit and COBOL.Net

  1. Edwas says:

    Amazing! Not clear for me, how offen you updating your http://www.gennard.net.
    Thanks
    Edwas

Comments are closed.